Difference between revisions of "Visualizations"

From Wikibase Personal data
Jump to navigation Jump to search
 
(33 intermediate revisions by the same user not shown)
Line 9: Line 9:
  
 
For these reasons, we wish to split searches below into reusable components, but we are not there yet...   
 
For these reasons, we wish to split searches below into reusable components, but we are not there yet...   
−
== Visualizations ==
+
= Visualizations =
 
These are some of the visualizations we are building together.  
 
These are some of the visualizations we are building together.  
  
 +
== Facebook ==
 +
{{Project:Ecosystem/Facebook/Visualizations|state=collapsed}}
  
−
{| class="wikitable"
+
== Gig work ==
−
|-
+
{{Project:Gig/Visualizations|state=collapsed}}
−
! Data ecosystem !! Topic !! Visualization
 
−
|-
 
−
| Facebook's tools || various Facebook tools, and how they exchange information ||  [{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q383}}}}]
 
−
|-
 
−
| Facebook and disinformation || how disinformation blends into our information ecosystem through Facebook ||  [{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q366}}}}]
 
−
|-
 
−
| Cambridge Analytica scandal || visual summary ||  [{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q384}}}}]
 
−
|-
 
−
| Adtech ecosystem || [[adtech|routes your personal data takes when you browse the web]] || 
 
−
|-
 
−
| Scottish data ecosystem || [[MyData Scotland ecosystem mapping]] workshop ||
 
−
[{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q201}}}}]
 
−
[{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q227}}}}]
 
−
[{{SPARQLEmbed|query={{SPARQLTableQuery|table=Q228}}}}]
 
−
[{{SPARQLEmbed|query={{SPARQLWorkshopQuery|workshop=Q224}}}}]
 
−
|-
 
−
| Platform economy and work || workers contribute a lot of data to the [[gig work ecosystem]]  ||
 
−
|-
 
−
| MyDataLab Geneva|| [[Presentation_MyDataLab |workshop]] run in the context of the OpenGeneva festival ||
 
−
|-
 
−
| Open Science Hardware || [[Use case: GOSH | Mapping the Gathering for Open Science Hardware community]] ||
 
−
|-
 
−
| MyData ecosystem || [[MyData case bank]] ||
 
−
|-
 
−
| MyData Finland ecosystem || [[Mapping/Finland|Finnish ecosystem]] ||
 
−
[{{SPARQLEmbed|query={{SPARQLcountry|country=Q564}}}}]
 
−
|-
 
−
| MyData Japan ecosystem || [[Mapping/Japan|Japanese ecosystem]] ||
 
−
[{{SPARQLEmbed|query={{SPARQLcountry|country=Q681|legend=true}}}}]
 
−
|-
 
−
| Mobility data ecosystem || [[Mobility services|actors and activities in the mobility space]] ||
 
−
|-
 
−
| Open Science Hardware || [[Use case: GOSH | Mapping the Gathering for Open Science Hardware community]] ||
 
−
|}
 
  
 +
== Adtech ==
 +
{{Project:Adtech/Visualizations|state=collapsed}}
  
−
Of course, it is necessary for these visualisations to engage in a mapping process. We explain [https://www.youtube.com/watch?v=rcc9NoQGTsk here] how to do so.
+
== MyData ==
 +
{{Project:MyData/Visualizations|state=collapsed}}
 +
 
 +
=== Others ===
 +
* [[Presentation_MyDataLab |Open Geneva workshop]]
 +
* [http://tinyurl.com/y49p76ff Paul's Wikidata footprint]
 +
* [http://tinyurl.com/yyyk42d8 Sustainable development goals]
 +
* [https://www.wikidata.org/wiki/Wikidata:WikiProject_Sustainable_Development  WikiProject SDGs]
 +
* [http://tinyurl.com/y6r6mm7n OpenGeneva]
 +
* [http://tinyurl.com/y253gnam OpenGeneva hackathons]

Latest revision as of 00:06, 27 January 2020

We think producing quickly and efficiently visualisations that are maximally relevant to specific segments of our stakeholders is key to our success in engaging progressively more participants.

We find ourselves in a particularly virtuous feedback loop if we manage to put contributors in front of a simple interface (to them) to enter data, knowing that their work will directly translate into an outcome valuable to them. The easiest way to achieve that is to give them a perspective on their own work that they didn't have before, because they can then address their peers with already new information.

For this reason, we need to be able to produce high quality visualisations in an extremely modular way. There are several reasons for the modularity:

  • separation of concerns between querying the database for data and producing the visualisation itself;
  • modularity of either side;
  • access controls on components generating such requests.

For these reasons, we wish to split searches below into reusable components, but we are not there yet...

Visualizations

These are some of the visualizations we are building together.

Facebook

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?node ?nodeLabel ?nodeImage ?childNode ?childNodeLabel ?childNodeImage ?rgb WHERE {
  {
    BIND(pdio:Q308 AS ?node)
    ?node ?p ?i.
    OPTIONAL { ?node pdiot:P47 ?nodeImage. }
    ?childNode ?x ?p.
    ?childNode rdf:type wikibase:Property.
    FILTER(STRSTARTS(STR(?i), "https://wiki.personaldata.io/entity/Q"))
    FILTER(STRSTARTS(STR(?childNode), "https://wiki.personaldata.io/entity/P"))
  }
  UNION
  {
    BIND("EFFBD8" AS ?rgb)
    pdio:Q308 ?p ?childNode.
    OPTIONAL { ?childNode pdiot:P47 ?childNodeImage. }
    ?node ?x ?p.
    ?node rdf:type wikibase:Property.
    FILTER(STRSTARTS(STR(?childNode), "https://wiki.personaldata.io/entity/Q"))
  }
  OPTIONAL {
    ?node pdiot:P47 ?nodeImage.
    ?childNode pdiot:P47 ?childNodeImage.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Mickey Mouse's social network (embedded) 


PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?rel ?pred ?obj ?item ?domain ?domainLabel ?range ?rangeLabel WHERE
{
   BIND(pdio:Q383 AS ?table).
   OPTIONAL {
     ?table pdiop:P26 ?domain_prop.
     ?domain_prop pdiops:P26 ?domain.
     ?domain_prop pdiopq:P27 ?domainLabel
   }.
   OPTIONAL {
     ?table pdiop:P26 ?range_prop.
     ?range_prop pdiops:P26 ?range.
     ?range_prop pdiopq:P27 ?rangeLabel
   }.
   {
     SELECT ?domain ?range WHERE {
          ?table pdiop:P25 ?relationshipStatement.
          ?relationshipStatement pdiopq:P24 ?domain.
          ?relationshipStatement pdiopq:P23 ?range.
       }
     
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P58 ?relationshipInStatement.
          ?relationshipInStatement pdiops:P58 ?range.
          ?relationshipInStatement pdiopq:P61 ?domain.
       }
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P59 ?relationshipOutStatement.
          ?relationshipOutStatement pdiops:P59 ?domain.
          ?relationshipOutStatement pdiopq:P60 ?range.
       }
   }.
}

simple view of FB (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?origin ?originLabel ?destination ?destinationLabel ?rgb ?edgeLabel WHERE
{
   
   pdio:Q1044 pdiot:P129 ?origin.
   pdio:Q1044 pdiot:P129 ?destination.
   pdio:Q1044 pdiop:P130 ?association_statement.
   ?association_statement pdiopq:P131 ?origin.
   ?association_statement pdiopq:P132 ?destination.
   ?association_statement pdiops:P130 ?edge.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

extended view of FB (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?rel ?pred ?obj ?item ?domain ?domainLabel ?range ?rangeLabel WHERE
{
   BIND(pdio:Q383 AS ?table).
   OPTIONAL {
     ?table pdiop:P26 ?domain_prop.
     ?domain_prop pdiops:P26 ?domain.
     ?domain_prop pdiopq:P27 ?domainLabel
   }.
   OPTIONAL {
     ?table pdiop:P26 ?range_prop.
     ?range_prop pdiops:P26 ?range.
     ?range_prop pdiopq:P27 ?rangeLabel
   }.
   {
     SELECT ?domain ?range WHERE {
          ?table pdiop:P25 ?relationshipStatement.
          ?relationshipStatement pdiopq:P24 ?domain.
          ?relationshipStatement pdiopq:P23 ?range.
       }
     
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P58 ?relationshipInStatement.
          ?relationshipInStatement pdiops:P58 ?range.
          ?relationshipInStatement pdiopq:P61 ?domain.
       }
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P59 ?relationshipOutStatement.
          ?relationshipOutStatement pdiops:P59 ?domain.
          ?relationshipOutStatement pdiopq:P60 ?range.
       }
   }.
}

simple view of various Facebook tools, and how they exchange information (embedded) 


PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?origin ?originLabel ?destination ?destinationLabel ?rgb ?edgeLabel WHERE
{
   
   pdio:Q1044 pdiot:P129 ?origin.
   pdio:Q1044 pdiot:P129 ?destination.
   pdio:Q1044 pdiop:P130 ?association_statement.
   ?association_statement pdiopq:P131 ?origin.
   ?association_statement pdiopq:P132 ?destination.
   ?association_statement pdiops:P130 ?edge.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

extended view of various Facebook tools, and how they exchange information (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?rel ?pred ?obj ?item ?domain ?domainLabel ?range ?rangeLabel WHERE
{
   BIND(pdio:Q366 AS ?table).
   OPTIONAL {
     ?table pdiop:P26 ?domain_prop.
     ?domain_prop pdiops:P26 ?domain.
     ?domain_prop pdiopq:P27 ?domainLabel
   }.
   OPTIONAL {
     ?table pdiop:P26 ?range_prop.
     ?range_prop pdiops:P26 ?range.
     ?range_prop pdiopq:P27 ?rangeLabel
   }.
   {
     SELECT ?domain ?range WHERE {
          ?table pdiop:P25 ?relationshipStatement.
          ?relationshipStatement pdiopq:P24 ?domain.
          ?relationshipStatement pdiopq:P23 ?range.
       }
     
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P58 ?relationshipInStatement.
          ?relationshipInStatement pdiops:P58 ?range.
          ?relationshipInStatement pdiopq:P61 ?domain.
       }
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P59 ?relationshipOutStatement.
          ?relationshipOutStatement pdiops:P59 ?domain.
          ?relationshipOutStatement pdiopq:P60 ?range.
       }
   }.
}

how disinformation blends into our information ecosystem through Facebook (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?rel ?pred ?obj ?item ?domain ?domainLabel ?range ?rangeLabel WHERE
{
   BIND(pdio:Q384 AS ?table).
   OPTIONAL {
     ?table pdiop:P26 ?domain_prop.
     ?domain_prop pdiops:P26 ?domain.
     ?domain_prop pdiopq:P27 ?domainLabel
   }.
   OPTIONAL {
     ?table pdiop:P26 ?range_prop.
     ?range_prop pdiops:P26 ?range.
     ?range_prop pdiopq:P27 ?rangeLabel
   }.
   {
     SELECT ?domain ?range WHERE {
          ?table pdiop:P25 ?relationshipStatement.
          ?relationshipStatement pdiopq:P24 ?domain.
          ?relationshipStatement pdiopq:P23 ?range.
       }
     
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P58 ?relationshipInStatement.
          ?relationshipInStatement pdiops:P58 ?range.
          ?relationshipInStatement pdiopq:P61 ?domain.
       }
   }
   UNION
   {  
     SELECT ?domain ?range WHERE {
          ?table pdiop:P59 ?relationshipOutStatement.
          ?relationshipOutStatement pdiops:P59 ?domain.
          ?relationshipOutStatement pdiopq:P60 ?range.
       }
   }.
}

summary of the Cambridge Analytica scandal (embedded)


Gig work

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?origin ?originLabel ?destination ?destinationLabel ?rgb ?edgeLabel WHERE
{
   
   pdio:Q1070 pdiot:P129 ?origin.
   pdio:Q1070 pdiot:P129 ?destination.
   pdio:Q1070 pdiop:P130 ?association_statement.
   ?association_statement pdiopq:P131 ?origin.
   ?association_statement pdiopq:P132 ?destination.
   ?association_statement pdiops:P130 ?edge.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Uber systems (embedded)


Adtech

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?item ?itemLabel ?_image WHERE {
  ?item pdiot:P28 pdio:Q370.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
OPTIONAL { ?item pdiot:P47 ?_image. }
}
LIMIT 100

adtech mess... we need an ontology (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?label ?_image WHERE {
  ?item pdiot:P3 pdio:Q1588.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
  
OPTIONAL { ?item pdiot:P47 ?_image. }
}
LIMIT 100

partners lists (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT  ?object ?objectLabel ?rgb ?subject ?subjectLabel 
WHERE {
  VALUES (?object ?rgb){
       (pdio:Q110 "FF0000")
       (pdio:Q495 "00FF00")
       (pdio:Q559 "0000FF")
       (pdio:Q153 "333333")
       (pdio:Q491 "888800")  
       (pdio:Q807 "008888")
       (pdio:Q492 "880088")
       (pdio:Q498 "440000")
       (pdio:Q810 "004400")
       (pdio:Q556 "000044")
       (pdio:Q504 "004444")
       (pdio:Q874 "444400")
       (pdio:Q834 "440044")
    }
  VALUES ?predicate {
       pdiot:P3
       pdiot:P28
    } 
  ?subject ?predicate ?object
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
}
LIMIT 1000

Lumascape-like map of the ecosystem (embedded) 


PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?label ?_image WHERE {
  ?item pdiot:P3 pdio:Q110.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
OPTIONAL { ?item pdiot:P47 ?_image. }
}
LIMIT 100

adtech companies (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?label ?_image WHERE {
  ?item pdiot:P37 pdio:Q495.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
OPTIONAL { ?item pdiot:P47 ?_image. }
}
LIMIT 100

data management platforms (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?label ?_image WHERE {
  ?item pdiot:P37 pdio:Q559.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
OPTIONAL { ?item pdiot:P47 ?_image. }
}
LIMIT 100

identity resolution services (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?item1 ?item1Label ?rgb ?item2 ?item2Label
WITH {
  SELECT ?predicateFilterValue ?predicateFilterValueRGB WHERE {
    VALUES (?predicateFilterValue ?predicateFilterValueRGB) {
       (pdio:Q110 "EEEEEE")(pdio:Q495 "222288")(pdio:Q559 "8822222")
    }  
  }
}
AS %predicateFilterValues
WITH {
  SELECT ?predicate ?subjectValue ?objectValue ?predicateRGB  WHERE {
    VALUES (?predicate ?subjectValue ?objectValue ?predicateRGB) {
     (pdiot:P111 pdio:Q495 pdio:Q559 "EEEEEE")(pdiot:P111 pdio:Q495 pdio:Q559 "222288")
    }
  }
}
AS %predicates
WITH {SELECT ?node ?nodeRGB WHERE {
    
    ?node pdiot:P3 ?predicateFilterValue.
    INCLUDE %predicateFilterValues.
    BIND(?predicateFilterValueRGB AS ?nodeRGB)
  }
}
AS %nodes
WITH {SELECT ?subject ?object ?edgeRGB WHERE {
    INCLUDE %predicates.
    ?subject pdiot:P3 ?subjectValue.
    ?object pdiot:P3 ?objectValue.
    ?subject ?predicate ?object.
    # This is filtering for each edge twice, potentially a huge waste: |E|*|V| instead of |V|
    
    
    BIND(?predicateRGB as ?edgeRGB)
  }
} AS %edges
WHERE {
{ # The caption's nodes: 
     INCLUDE %predicateFilterValues.
     BIND(?predicateFilterValue AS ?item1).
     BIND(?predicateValueRGB AS ?rgb).
  } 
  UNION
  { # The caption's edges: 
     INCLUDE %predicates.
     BIND(?subjectValue AS ?item1).
     BIND(?objectValue AS ?item2).
     BIND(?predicateRGB AS ?rgb).
  }
  UNION
  {  
     INCLUDE %nodes.
     BIND(?node AS ?item1).
     BIND(?nodeRGB AS ?rgb).
  }
  UNION
  {  
     INCLUDE %edges.
     BIND(?subject AS ?item1).
     BIND(?object AS ?item2).
     BIND(?edgeRGB AS ?rgb).
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
}
LIMIT 10000

actors (embedded)


MyData

Network

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?itemLabel WHERE {
  ?item pdiot:P3 pdio:Q47.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
}

MyData hubs (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?node ?nodeLabel ?value ?valueLabel ?edgeLabel   
(IF(BOUND(?edge), ?propertyrgb, "FFFFFF") AS ?rgb) #white
{
  VALUES (?propertyRel ?propertyrgb)
  {
      (pdiot:P57 "880000")   # red - activity 
      (pdiot:P55 "00AA00")   # light green - country
      (pdiot:P137 "0000AA")  # blue - partner
      (pdiot:P145 "AA00AA")  # pink - seeks
      (pdiot:P11 "00AAAA")  #  interested in
  }
  pdio:Q49 pdiot:P63 ?node.
  OPTIONAL
  {
    ?node ?propertyRel ?value.
    ?edge wikibase:directClaim ?propertyRel.
  }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

MyData hub network (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?itemLabel ?country ?countryLabel WHERE {
  ?item pdiot:P3 pdio:Q646.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
  OPTIONAL { ?item pdiot:P55 ?country. }
}

data operators around the world (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?itemLabel ?country ?countryLabel ?location ?locationLabel WHERE {
  ?item pdiot:P3 pdio:Q401.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
  }
OPTIONAL { ?item pdiot:P55 ?country. }
OPTIONAL { ?item pdiot:P80 ?location. } }

associations, with country and location (embedded)


Hub initiators meeting work

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
#defaultView:Graph
SELECT ?item ?itemLabel ?object ?objectLabel ?edgeLabel WHERE {
  ?item ?rel ?object.
  ?edge wikibase:directClaim ?rel.
  ?item pdiot:P3 pdio:Q47.
  MINUS {pdio:P3 wikibase:directClaim ?rel}
  ?edge wikibase:propertyType wikibase:WikibaseItem   #If we don't remove this, then those properties pointing to non-item labels mess everything up
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 1000

Hub Initiators meeting map (embedded) 

PREFIX pdio: <https://wiki.personaldata.io/entity/>
PREFIX pdiot: <https://wiki.personaldata.io/prop/direct/>
PREFIX pdiop: <https://wiki.personaldata.io/prop/>
PREFIX pdiops: <https://wiki.personaldata.io/prop/statement/>
PREFIX pdiopq: <https://wiki.personaldata.io/prop/qualifier/>
SELECT ?item ?itemLabel  ?edgeLabel ?object ?objectLabel WHERE {
  ?item ?rel ?object.
  ?edge wikibase:directClaim ?rel.
  ?item pdiot:P3 pdio:Q47.
  MINUS {pdio:P3 wikibase:directClaim ?rel}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 1000

full triple table of Hub initiators meeting (embedded)


On Wikidata

Others

Retrieved from "https://wiki.personaldata.io/w/index.php?title=Visualizations&oldid=77241"